Histórico da Página

...

Bloco de código

title	Ejemplo de Punto de Entrada M486RNF

#include "protheus.ch"

User Function M486RNF()
    Local cXMLPE := ""
    Local cCRLF    := (chr(13)+chr(10))
    Local cOpc    := PARAMIXB[1] //Opción N - Notas, P - Pallets/Contenedor/Precinto
    Local cCodDoc := IIf(cOpc=="R",PARAMIXB[2],"")  //cbc:DocumentTypeCode
    Local cDesTpD := ""
    Local cTpDocC := "4"
    Local cNumIdC := "A43594617"
    Local cNomCom := "Razon Social Comprador"      

    If cOpc == "N" //Observaciones
        cXMLPE += '	<cbc:Note>Prueba del PE M486RNF</cbc:Note>' + cCRLF  
    ElseIf cOpc == "P" //número de Pallets
        If Alltrim(SF2->F2_MODTRAD) == "01" //Importación
            cXMLPE += '		<cbc:TotalTransportHandlingUnitQuantity>80</cbc:TotalTransportHandlingUnitQuantity>' + cCRLF
        EndIf
    ElseIf cOpc == "S" //Shipment
        cXMLPE += '		<cbc:HandlingInstructions>DESCRIPCION DEL MOTIVO DE TRASLADO</cbc:HandlingInstructions>' + cCRLF
    ElseIf cOpc == "DA" //Establecimiento
        cXMLPE += '			<cbc:AddressTypeCode listAgencyName="PE:SUNAT" listName="Establecimientos anexos" listID="20552174918">3985</cbc:AddressTypeCode>' + cCRLF 
    ElseIf cOpc == "CO" //Número de Contenedor y Número de Precinto
        cXMLPE += '			<cac:Package>' + cCRLF
        cXMLPE += '				<cbc:ID>hlxu2142141</cbc:ID>' + cCRLF
        cXMLPE += '				<cbc:TraceID>002jp00124</cbc:TraceID>' + cCRLF
        cXMLPE += '			</cac:Package>' + cCRLF
    ElseIf cOpc == "R" //AdditionalDocumentReference
        If cCodDoc == "01"
            cDesTpD := "FACTURA"
        ElseIf cCodDoc == "50" 
            cDesTpD := EncodeUtf8("Declaración Aduanera de Mercancías")
        EndIf
        cXMLPE += '		<cbc:DocumentType>' + cDesTpD + '</cbc:DocumentType>' + cCRLF
    ElseIf cOpc == "PU" //MTC
        cXMLPE += '				<cbc:CompanyID>0200310CNG</cbc:CompanyID>' + cCRLF
    ElseIf cOpc == "CP" //Datos del Comprado / Datos del Proveedor
        //DATOS DEL COMPRADOR
        If SF2->F2_MODTRAD == "03" //Motivo de Traslado 03 - Venta con entrega a terceros
            cXMLPE := space(4) + '<cac:BuyerCustomerParty>' + cCRLF
            cXMLPE += space(9) + '<cac:Party>' + cCRLF
            cXMLPE += space(14) + '<cac:PartyIdentification>' + cCRLF
            cXMLPE += space(19) + '<cbc:ID schemeID="' + cTpDocC + '" schemeName="Documento de Identidad" schemeAgencyName="PE:SUNAT"       schemeURI="urn:pe:gob:sunat:cpe:see:gem:catalogos:catalogo06">' + cNumIdC + '</cbc:ID>' + cCRLF
            cXMLPE += space(14) + '</cac:PartyIdentification>' + cCRLF
            cXMLPE += space(14) + '<cac:PartyLegalEntity>' + cCRLF
            cXMLPE += space(19) + '<cbc:RegistrationName>' + cNomCom + '</cbc:RegistrationName>' + cCRLF
            cXMLPE += space(14) + '</cac:PartyLegalEntity>' + cCRLF
            cXMLPE += space(9) + '</cac:Party>' + cCRLF
            cXMLPE += space(4) + '</cac:BuyerCustomerParty>' + cCRLF
        EndIf     
    EndIf
    
Return cXMLPE

Informações

title	Importante

Informações

title	Información

El Punto de Entrada M486RNF recibe como parámetro la opción de tipo Caracter, mediante el cual se tienen disponibles las siguientes opciones:

Si opción es "N", se permite la generación del Nodo de Observaciones.

Si opción es "P", permite la generación del nodo de Número de Bultos o Pallets, de igual manera se pueden generar los indicadores utilizando los tag cbc:SpecialInstructions.

Si opción es "S", permite la generación del tag cbc:HandlingInstructions con la descripción del Motivo de Traslado.

Si opción es "DA", permite la generación del tag cbc:AddressTypeCode con el código de establecimiento de llegada.

Si opción es "CO", permite la generación del tag cac:Package con los datos de Número de Contenedor y Número de Precinto.

Si opción es "R", permite la generación del tag cbc:DocumentType con la descripción del tipo de Documento de Referencia, recibiendo el segundo parámetro con el código del tipo de documento de referencia.

Si opción es "PU", permite la generación del tag cbc:CompanyID el número de MTC del Transportista.

Se debe retornar en un string los nodos generados de acuerdo a lo permitido por la guía de Guías de Remisión Electrónica definido por la SUNAT.

Se tiene acceso disponible a los campos de la tabla SF2 - Encabezado de Fact. de Salida por el posicionamiento previo a la tabla, y es importante realizar las bifurcaciones de manera correcta para la generación de los nodos y en caso de requerir utilizar el Motivo de Traslado se puede utilizar el campo Motivo Tras (F2_MODTRAD).

...

Árvore de páginas

Versões comparadas

Versão antiga 148

Nova versão 149

Chave