Informações | ||
---|---|---|
| ||
Novos métodos para objeto de negócio localizado disponíveis a partir da LIB Label 20230626 |
Índice | ||||
---|---|---|---|---|
|
Nesta documentação teremos os novos métodos implementados, para que sejam utilizados nos objetos de negócio que serão personalizados por localização.
Alguns pré-requisitos para esta implementação:
Método que será chamado antes do getSchema(), aqui poderão ser adicionados novos campos para o schema, que não estão no schema principal e que poderão ser campos novos, campos totalizadores, campos que só existem em um país específico etc.
Método que será chamado antes do getData(), esse método pode ser utilizado para fazer a query atualizada com os campos que poderão ser adicionados no objeto de negócio localizado ou para adicionar o where que deverá ser localizado.
Este método deverá ser chamado antes do envio dos dados no getData() para que sejam adicionados os dados dos campos que estão no objeto de negócio localizado.
Sempre teremos um objeto de negócio padrão, com o annotation country=ALL, todas as informações desse objeto serão herdadas para o objeto de negócio localizado.
A partir disso as informações/dados do localizado deverão ser adicionadas em outro fonte herdando a classe principal. Mais abaixo deixarei um exemplo.
Sugerimos a utilização de propriedades na classe para que a mesma fique visível nos objetos, se forem utilizadas variáveis locais o objeto localizado não herdará essas variáveis.
Se eu tenho a classe MATR190TReportsBusinessObject como objeto de negócio padrão, assim ficará o annotation e herança da classe:
Bloco de código | ||
---|---|---|
| ||
@totvsFrameworkTReportsIntegratedProvider(active=.T., tables="SA5", country="ALL")
class MATR190TReportsBusinessObject from totvs.framework.treports.integratedprovider.IntegratedProvider |
Para o objeto de negócio localizado para o país ARG, teremos a seguinte mudança:
Bloco de código | ||
---|---|---|
| ||
@totvsFrameworkTReportsIntegratedProvider(active=.F., tables="SA5", country="ARG")
class MATR190TReportsBusinessObjectARG from custom.materiais.MATR190TReportsBusinessObject |
Obs.: O objeto de negócio localizado herda a classe principal (padrão) que foi criada e deverá vir com o active=.F. para que não apareça duplicado no TReports
Fonte padrão:
Bloco de código | ||
---|---|---|
| ||
#include "msobject.ch"
#include "protheus.ch"
#include "apcfg021.ch"
#include "totvs.framework.treports.integratedprovider.th"
namespace custom.materiais
//-------------------------------------------------------------------
/*{Protheus.doc} MATR190TReportsBusinessObject
Classe para criação do Objeto de Negócio de Prod x Forn para o TReports
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
@totvsFrameworkTReportsIntegratedProvider(active=.T., tables="SA5", country="ALL")
class MATR190TReportsBusinessObject from totvs.framework.treports.integratedprovider.IntegratedProvider
public method new() as object
public method getDisplayName() as character
public method getDescription() as character
public method getData() as object
public method getSchema() as object
//Definição das propriedades da classe que ficarão visíveis para as classes que herdarão
protected data aFields as array
protected data aStruct as array
protected data cQuery as character
protected data cWhere as character
protected data jItems as json
endclass
//-------------------------------------------------------------------
/*{Protheus.doc} new
Método de instância da classe
@return object: self
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
method new() class MATR190TReportsBusinessObject
_Super:new()
self:appendArea("Compras")
self:aFields := {"A5_LOJA", "A5_NOMEFOR", "A5_PRODUTO"} //Defino os campos padrões em uma propriedade da classe
return self
//-------------------------------------------------------------------
/*{Protheus.doc} getDisplayName
Retorna o nome de exibição do objeto de negócio
@return string
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
method getDisplayName() as character class MATR190TReportsBusinessObject
return "Produtos x Fornecedores - Localizado"
//-------------------------------------------------------------------
/*{Protheus.doc} getDescription
Retorna a descrição do objeto de negócio
@return string
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
method getDescription() as character class MATR190TReportsBusinessObject
return "Produtos x Fornecedores"
//-------------------------------------------------------------------
/*{Protheus.doc} getData
Retorna os dados do objeto de negócio
@param nPage, numérico, indica a página atual do relatório
@param oFilter, objeto, contém o filtro do TReports
@return object: self:oData
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
method getData(nPage as numeric, oFilter as object) as object class MATR190TReportsBusinessObject
local cAlias as character
local nSkip as numeric
local nCount as numeric
local nX as numeric
local aPDFields as array
local cFieldsQry as character
nCount := 0
cFieldsQry := ArrTokStr(self:aFields, ",")
self:cQuery := "SELECT "
self:cQuery += cFieldsQry
self:cQuery += " FROM " + RetSQLName("SA5")
if !empty(self:cWhere)
self:cQuery += self:cWhere
endif
//Os filtros serão setados na interface do novo TReports
if oFilter:hasFilter()
self:cQuery += " AND " + oFilter:getSQLExpression()
endif
cAlias := MPSysOpenQuery(self:cQuery)
if nPage == 1
(cAlias)->(dbGoTop())
else
//Encontra a quantidade de itens que irá pular de acordo com a página atual
nSkip := ((nPage - 1) * self:getPageSize())
(cAlias)->(dbSkip(nSkip))
endif
while !(cAlias)->(Eof())
//Verifica se precisa fazer o tratamento para LGPD
aPDFields := FwProtectedDataUtil():UsrAccessPDField(__cUserID, self:aFields)
lObfuscated := len( aPDFields ) != Len(self:aFields)
self:jItems := JsonObject():new()
for nX := 1 To Len(self:aStruct)
if lObfuscated .and. aScan(aPDFields, self:aStruct[nX][5]) == 0
self:jItems[self:aStruct[nX][1]] := FwProtectedDataUtil():ValueAsteriskToAnonymize((cAlias)->&(self:aStruct[nX][5]))
else
self:jItems[self:aStruct[nX][1]] := (cAlias)->&(self:aStruct[nX][5])
endif
next nX
self:processData() //Método deverá ser chamado antes do appendData pois irá popular o json self:jItems
self:oData:appendData(self:jItems)
(cAlias)->(DBSkip())
nCount++
//Sai do loop quando chegar no tamanho de itens da página
if nCount == self:getPageSize()
exit
endif
enddo
//Se não for o último registro indica que terá próxima página
self:setHasNext(!(cAlias)->(Eof()))
(cAlias)->(DBCloseArea())
return self:oData
//-------------------------------------------------------------------
/*{Protheus.doc} getSchema
Retorna a estrutura dos campos
@return object: self:oSchema
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
method getSchema() as object class MATR190TReportsBusinessObject
Local nX as numeric
self:aStruct := getStruct(self:aFields)
for nX := 1 To Len(self:aStruct)
self:addProperty(self:aStruct[nX][1], self:aStruct[nX][2], self:aStruct[nX][3], self:aStruct[nX][4], self:aStruct[nX][5])
Next nX
return self:oSchema
//-------------------------------------------------------------------
/*{Protheus.doc} getStruct
Prepara a estrutura dos campos
@param aCpos array: Array com os campos do relatório
@return array: Array com a estrutura dos campos
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
function getStruct(aCpos)
Local aDeParaCpo as array
Local aCpoTmp as array
Local cCampo as character
Local cCpoQry as character
Local cTipR as character
Local nPos as numeric
Local nC as numeric
aDeParaCpo := {{"C", "string"}, {"D", "date"}, {"N", "number"}, {"L", "boolean"}}
aCpoTmp := {}
for nC := 1 to Len(aCpos)
cCpoQry := aCpos[nC]
nPos := AT(".", aCpos[nC]) + 1
if nPos > 0
cCampo := Substr(cCpoQry, nPos)
else
cCampo := cCpoQry
endif
cTipo := GetSx3Cache(cCampo, "X3_TIPO")
if (nPos := aScan(aDeParaCpo, {|c| c[01] = cTipo})) > 0
cTipR := aDeParaCpo[nPos, 02]
else
cTipR := "string"
endif
AAdd(aCpoTmp, {strTran(cCampo, "_", ""), FWSX3Util():GetDescription(cCampo), cTipR, cCampo, cCampo})
next nC
return (aCpoTmp) |
Fonte localizado (ARG):
Bloco de código |
---|
#include "msobject.ch"
#include "protheus.ch"
#include "totvs.framework.treports.integratedprovider.th"
namespace custom.materiais
//-------------------------------------------------------------------
/*{Protheus.doc} MATR190TReportsBusinessObjectARG
Classe para criação do Objeto de Negócio de Prod x Forn para o TReports
Localizado para a Argentina
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
@totvsFrameworkTReportsIntegratedProvider(active=.F., tables="SA5", country="ARG") //O active deverá vir como .F. para que o objeto não fique duplicado
/*Aqui será herdada a classe padrão criada anteriormente, o nome da classe localizada deverá ser a padrão + sigla do país (cPaisLoc)*/
class MATR190TReportsBusinessObjectARG from custom.materiais.MATR190TReportsBusinessObject
public method new() as object
public method preData() as object
public method processData() as object
public method preSchema() as object
protected data aFields as array
protected data aStruct as array
endclass
//-------------------------------------------------------------------
/*{Protheus.doc} new
Método de instância da classe que herdará a principal
@return object: self
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
method new() class MATR190TReportsBusinessObjectARG
_Super:new()
aAdd(self:aFields, "A5_FORNECE")
return self
//-------------------------------------------------------------------
/*{Protheus.doc} preData
Método chamado antes do getData do objeto principal
@return object: self:oData
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
method preData() as object class MATR190TReportsBusinessObjectARG
self:cWhere := " WHERE D_E_L_E_T_ = ' '"
return self:oData
//-------------------------------------------------------------------
/*{Protheus.doc} processData
Deverá ser chamado no momento do processamento da query
@return object: self:oData
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
method processData() as object class MATR190TReportsBusinessObjectARG
self:jItems["Observacao"] := "Teste Localizado"
self:jItems["Totalizador"] := "1220"
return
//-------------------------------------------------------------------
/*{Protheus.doc} preSchema
Método chamada antes do getSchema do objeto principal
@return object: self:oSchema
@author Vanessa Ruama
@since 02/03/2023
@version 1.0
*/
//-------------------------------------------------------------------
method preSchema() as object class MATR190TReportsBusinessObjectARG
self:addProperty("Observacao", "Observacao", "string", "Observacao", "Observacao")
self:addProperty("Totalizador", "Totalizador", "string", "Totalizador", "Totalizador")
return self:oSchema |