Histórico da Página

#include "totvs.ch"

//-------------------------------------------------------------------
/*/{Protheus.doc}

Personalização desenvolvida com o objetivo de demonstrar uma forma de 
atualizar o Código SIAF durante processo de inclusão do Documento de Entrada.


Utilizada para os casos em que o Local da Prestação do Serviço for diferente 
do local do estabelecimento do Prestador, visando atender a legislação
contemplada pela DMSCAMP

Este código é de caráter exemplificativo, sendo de responsabilidade do cliente 
realizar a adequação para atender as regras de negócio de sua organização.

@author Equipe Desenvolvimento Fiscal

/*/
//-------------------------------------------------------------------  
User Function CODSIAFI( aParam )
Local aAreaOld := GetArea()

Local cCodSiafi:= Space(04)

Local oDlg_Siafi
Local oGroup

If FunName() == "MATA910"
   cCodSiafi := SF1->F1_CODSIAF
Endif

/*----------------------------------------------------------------------------------*\
| Tela para permitir selecionar Codigo SIAF                                          |
\*----------------------------------------------------------------------------------*/
DEFINE MSDIALOG oDlg_Siafi FROM 0,0 TO 175,350 PIXEL TITLE "Selecione Código SIAFI"
   
   oGroup:= tGroup():New(0,0,140,260,'',oDlg_Siafi,,,.T.)
   @ 013, 010 SAY "Código SIAFI " SIZE 50, 10 OF oGroup PIXEL
   @ 010, 050 MSGET oGet1 VAR cCodSiafi HASBUTTON F3 "CC2SIA" SIZE 50, 10 OF oGroup PIXEL

	DEFINE SBUTTON FROM 50, 80 TYPE 1 ACTION oDlg_Siafi:End() ENABLE OF oDlg_Siafi

ACTIVATE MSDIALOG oDlg_Siafi CENTERED

If !empty( cCodSiafi )	
	RecLock("SF1", .F.)
	SF1->F1_CODSIAF := 	cCodSiafi
	MsunLock()
Endif

RestArea( aAreaOld )

Return