Histórico da Página

#INCLUDE "PROTHEUS.CH" 

User Function ConsEst()

Local oSvc := Nil //Objeto para WebService
Local lRet := .F. //Retorno do WS
Local cFilCons := "D SP 01" //Filial que sera efetuada a consulta
Local cPrdCons := "1"       //Produto que sera consultado
Local cLocCons := "01"      //Local de estoque que sera consultado
Local aProdEst := {}        //Retorno do WS após a consulta

//Conecta no ambiente
RpcSetEnv("T1","D SP 01")

cPrdCons := PadR(cPrdCons,TamSx3("B1_COD")[1])
cFilCons := PadR(cFilCons,TamSx3("B1_FILIAL")[1])
cLocCons := PadR(cLocCons,TamSx3("B1_LOCPAD")[1])

//Inicia conexao com o WebService para consulta de estoque
oSvc        := WSLOJESTOQUE():New()                 
oSvc:_URL   := "http://127.0.0.1:81/LOJESTOQUE.apw"
lRet        := oSvc:ConEstoque(cEmpAnt,cFilAnt , cFilCons, cPrdCons, cLocCons)

If lRet 
	//Retorna array com o estoque do produto	
	If Len(oSvc:oWSCONESTOQUERESULT:oWSWSRETETQ) > 0  
		aAdd( aProdEst, {	oSvc:oWSCONESTOQUERESULT:oWSWSRETETQ[1]:cCFIL  	,;		//01 - Filial	
						oSvc:oWSCONESTOQUERESULT:oWSWSRETETQ[1]:cCPRODUTO	,;      //02 - Codigo do produto
						oSvc:oWSCONESTOQUERESULT:oWSWSRETETQ[1]:cCLOCALPROD	,;      //03 - Local do produto				 
						oSvc:oWSCONESTOQUERESULT:oWSWSRETETQ[1]:cCUNIDADE	,;      //04 - Unidade de medida do Produto	
						oSvc:oWSCONESTOQUERESULT:oWSWSRETETQ[1]:cCGRUPO		,;      //05 - Grupo do produto
						oSvc:oWSCONESTOQUERESULT:oWSWSRETETQ[1]:cCDESCRI	,;      //06 - Descricao do produto 
						oSvc:oWSCONESTOQUERESULT:oWSWSRETETQ[1]:nNINICIAL	,;      //07 - Quantidade inicial do produto	
						oSvc:oWSCONESTOQUERESULT:oWSWSRETETQ[1]:nNATUAL		,;      //08 - Saldo atual do produto 
						oSvc:oWSCONESTOQUERESULT:oWSWSRETETQ[1]:nNPRECO1	,;      //09 - Preco 1 
						oSvc:oWSCONESTOQUERESULT:oWSWSRETETQ[1]:nNPRECO2	,;      //10 - Preco 2 
						oSvc:oWSCONESTOQUERESULT:oWSWSRETETQ[1]:nNPRECO3	,;      //11 - Preco 3 
						oSvc:oWSCONESTOQUERESULT:oWSWSRETETQ[1]:nNPRECO4	,;      //12 - Preco 4 
						oSvc:oWSCONESTOQUERESULT:oWSWSRETETQ[1]:nNPRECO5	,;      //13 - Preco 5 
						oSvc:oWSCONESTOQUERESULT:oWSWSRETETQ[1]:nNPRECO6	,;      //14 - Preco 6 
						oSvc:oWSCONESTOQUERESULT:oWSWSRETETQ[1]:nNPRECO7	,;      //15 - Preco 7 
						oSvc:oWSCONESTOQUERESULT:oWSWSRETETQ[1]:nNPRECO8	,;      //16 - Preco 8 
						oSvc:oWSCONESTOQUERESULT:oWSWSRETETQ[1]:nNPRECO9	})      //17 - Preco 9 
	EndIf
EndIf

Return aProdEst