Histórico da Página

Descrição:

Fornece um objeto com o modelo hierárquico dos campos de edição para o Microsiga Protheus.
Esta classe é uma herança da classe modelo FWFormModel, utilizada apenas para facilitar o desenvolvimento do padrão MVC no Protheus.
Ela realiza alguns tratamentos que facilitam o desenvolvimento:
- Tratamento da função Help: Não é necessário usar o método SetErrorMessage para informar erros durante alguma validação, basta usar a função Help e a classe irá manipulá-la para setar os erros no Model.
- Criação de variáveis de memória.
- Função de gravação dos dados no dicionário de dados, ou seja, só é necessário criar a gravação dos dados manualmente em casos mais complexos.

Métodos:

New

Sintaxe:
MPFORMMODEL():New(< cID >, < bPre >, < bPost >, < bCommit >, < bCancel >)-> NIL

Descrição:
Método construtor da classe.

Parâmetros:

Exemplo:
Static Function ModelDef()
Local oModel := MPFormModel():New('COMP011MODEL', , { |oMdl| COMP011POS( oMdl ) })
Return

Static Function COMP011POS( oModel )
Local nOperation := oModel:GetOperation()
Local lRet := .T.

If nOperation == MODEL_OPERATION_UPDATE
   If Empty( oModel:GetValue( 'ZA0MASTER', 'ZA0_DTAFAL' ) )
      Help( ,, 'HELP',, 'Informe a data', 1, 0)      
      lRet := .F.
   EndIf
EndIf

Return lRet

Observações:
Se a aplicação é uma Function, o identificador (cID) do modelo de dados (Model) pode ter o mesmo nome da função principal e esta prática é recomendada para facilitar a codificação. Por exemplo, se estamos escrevendo a função XPTO, o identificador (cID) do modelo de dados (Model) poderá ser XPTO.
Se a aplicação é uma User Function, o identificador (ID) do modelo de dados (Model) NÃO pode ter o mesmo nome da função principal. Isso ocorre por causa dos pontos de entrada que já são criados automaticamente quando desenvolvemos uma aplicação em MVC.

User Function COMP011_MVC
Local oModel := MPFormModel():New("COMP011")
Return

Function COMP012_MVC
Local oModel := MPFormModel():New("COMP012_MVC")
Return




Activate
Sintaxe:
MPFORMMODEL():Activate(< lCopy >)-> NIL

Descrição:
Método de ativação da classe. Esse método deve ser usado depois que o objeto já foi completamente definido, pois após a ativação não será mais possível realizar definições, tais como addField, addGrid, setActivate e etc..
Quando a classe é ativada, os dados do submodelo são carregados.

Parâmetros:

Observações:
Este método realiza algumas validações no preenchimento dos parâmetros de operação da classe, gerando uma exceção caso haja algum problema de configuração.




AddFields
Sintaxe:
MPFORMMODEL():AddFields(< cId >, < cOwner >, < oModelStruct >, < bPre >, < bPost >, < bLoad >)-> NIL

Descrição:
Adiciona ao modelo um submodelo de edição por campo (FormField).
Um submodelo do tipo Field permite manipular somente um registro por vez. Ele tem um relacionamento do tipo 1xN ou 1x1 com outros SubModelos ou então não tem nenhum relacionamento.

Parâmetros:

Exemplo:

Static Function ModelDef()
Local oModel
Local oStruZA1:= FWFormStruct(1,'ZA1')
Local bPre := {|oFieldModel, cAction, cIDField, xValue| validPre(oFieldModel, cAction, cIDField, xValue)}
Local bPos := {|oFieldModel|fieldValidPos(oFieldModel)}
Local bLoad := {|oFieldModel, lCopy| loadField(oFieldModel, lCopy)}


oModel := MPFormModel():New('COMP021')
oModel:addFields('ZA1MASTER',,oStruZA1,bPre,bPos,bLoad)

Return oModel

Static Function fieldValidPos(oFieldModel)
Local lRet := .T.
   
   If "MUSICA" $ Upper(oFieldModel:GetValue("ZA1_TITULO"))
      lRet := .F.      
      Help( ,, 'HELP',, 'O texto "musica" não pode estar contido no título.', 1, 0)      
   EndIf
   
Return lRet

Static Function validPre(oFieldModel, cAction, cIDField, xValue)
Local lRet := .T.

If cAction == "SETVALUE" .And. cIDField == "ZA1_FILIAL"
   lRet := .F.   
   Help( ,, 'HELP',, 'Não possível atribuir valor ao campo Filial.', 1, 0)   
Return

Return lRet

Static Function loadField(oFieldModel, lCopy)
Local aLoad := {}

   aAdd(aLoad, {xFilial("ZA1"), "000001", "Musica 1", Date(), "R"}) //dados
   aAdd(aLoad, 1) //recno
      
Return aLoad

Observações
O primeiro SubModelo do Model deve ser, obrigatoriamente, um FormField.

Veja também
FWFormModelStruct
FWFormStruct
FWFormFieldModel




AddGrid
Sintaxe:
MPFORMMODEL():AddGrid(< cId >, < cOwner >, < oModelStruct >, < bLinePre >, < bLinePost >, < bPre >, < bPost >, < bLoad >)-> NIL

Descrição:
Adiciona ao modelo um submodelo de edição por grid (FormGrid). 
Um submodelo do tipo Grid permite manipular diversos registros por vez. Ele tem um relacionamento do tipo Nx1 ou NxM com outros Submodelos.

Parâmetros:

Exemplo:
Static Function ModelDef()
Local oModel
Local oStruZA1:= FWFormStruct(1,'ZA1')
Local oStruZA2 := FWFormStruct( 1, 'ZA2')
Local bLinePre := {|oGridModel, nLine, cAction, cIDField, xValue, xCurrentValue| linePreGrid(oGridModel, nLine, cAction, cIDField, xValue, xCurrentValue)}
Local bLoad := {|oGridModel, lCopy| loadGrid(oGridModel, lCopy)}

oModel := MPFormModel():New('COMP021')
oModel:AddFields('ZA1MASTER',,oStruZA1)
oModel:AddGrid( 'ZA2DETAIL', 'ZA1MASTER', oStruZA2, bLinePre, , , ,bLoad)
Return oModel

Static Function loadGrid(oGridModel, lCopy)
Local aLoad := {}

   aAdd(aLoad,{0,{xFilial("ZA2"), "000001", "01", "000100","AUTOR1","AUTOR"}})
   aAdd(aLoad,{0,{xFilial("ZA2"), "000001", "02", "000102","AUTOR2","AUTOR"}})
   aAdd(aLoad,{0,{xFilial("ZA2"), "000001", "03", "000104","AUTOR3","AUTOR"}})
   aAdd(aLoad,{0,{xFilial("ZA2"), "000001", "04", "000105","AUTOR4","AUTOR"}})
   aAdd(aLoad,{0,{xFilial("ZA2"), "000001", "05", "000106","AUTOR5","AUTOR"}})

Return aLoad

Static Function linePreGrid(oGridModel, nLine, cAction, cIDField, xValue, xCurrentValue)
Local lRet := .T.   

   If cAction == "SETVALUE"
      If oGridModel:GetValue("ZA2_TIPO") == "AUTOR"
         lRet := .F.         
         Help( ,, 'HELP',, 'Não é possível alterar linhas do tipo Autor', 1, 0)
      EndIf
   EndIf
   
Return lRet

Observações:
O Model deve sempre iniciar com um submodelo do tipo Field

Veja também:
FWFormGridModel
FWFormModelStruct




GetWhenFields
Sintaxe:
MPFORMMODEL():GetWhenFields(< cIdForm >)-> aRet

Descrição:
Retorna array com os campos que precisam ser avaliados no When

Parâmetros:

Retorno:
aRet Array unidimensional com os campos que precisam ser avaliados no When




DeActivate
Sintaxe:
MPFORMMODEL():DeActivate()-> NIL

Descrição:
Método de desativação da classe. Quando a classe é desativada, os dados do submodelo são perdidos e o objeto passa a aceitar novamente os métodos de parametrização, tais como addField, setActivate e etc.

Este método deve ser utilizado para reparametrizar a classe ou para reinicializar o preenchimento do submodelo.




SetVldActivate
Sintaxe:
MPFORMMODEL():SetVldActivate(< bBloco >)-> NIL

Descrição:
Seta um bloco que será chamado antes do Activate do model. Ele pode ser utilizado para inibir a inicialização do model. Se o retorno for negativo, uma exceção de usuário será gerada. O code-block recebe como parâmetro o objeto model.

Parâmetros:

Exemplo:

   bBloco := {|oModel| MinhaFunc(oModel)}
   oModel:SetVldActivate(bBloco)

Veja também:
CanActivate




SetPost
Sintaxe:
MPFORMMODEL():SetPost(< bBloco >, [ lAcumula ])-> NIL

Descrição:
Seta um bloco que será chamado para de validação do submodelo.

Parâmetros:

 
SetPre
Sintaxe:
MPFORMMODEL():SetPre(< bBloco >, [ lAcumula ])-> NIL

Descrição:
Seta um bloco que será chamado para a pré-validação do submodelo.

Parâmetros:

<style>
div.theme-default .ia-splitter #main {
    margin-left: 0px;
}
.ia-fixed-sidebar, .ia-splitter-left {
    display: none;
}
#main {
    padding-left: 10px;
    padding-right: 10px;
    overflow-x: hidden;
}

.aui-header-primary .aui-nav,  .aui-page-panel {
    margin-left: 0px !important;
}
.aui-header-primary .aui-nav {
    margin-left: 0px !important;
}
</style>