Histórico da Página

#INCLUDE "PROTHEUS.CH"
#INCLUDE "TBICONN.CH"

User Function MyPVLNFS()

    Local aPvlDocS := {}
    Local nPrcVen := 0
    Local cC5Num  := "pcpAO9"
    Local cSerie  := "001"
    Local cEmbExp := ""
    Local cDoc    := ""

    PREPARE ENVIRONMENT EMPRESA "T1" FILIAL "D MG 01 " MODULO "FAT" TABLES "SF2","SD2","SA1","SA2","SB1","SB2","SF4","SED","SE1"

    SC5->(DbSetOrder(1))
    SC5->(MsSeek(xFilial("SC5")+cC5Num))

    SC6->(dbSetOrder(1))
    SC6->(MsSeek(xFilial("SC6")+SC5->C5_NUM))

    // Obter os dados de cada item do pedido de vendas liberado para gerar o Documento de Saida
    While SC6->(!Eof() .And. C6_FILIAL == xFilial("SC6")) .And.;
            SC6->C6_NUM == SC5->C5_NUM

        SC9->(DbSetOrder(1))
        SC9->(MsSeek(xFilial("SC9")+SC6->(C6_NUM+C6_ITEM))) //FILIAL+NUMERO+ITEM

        SE4->(DbSetOrder(1))
        SE4->(MsSeek(xFilial("SE4")+SC5->C5_CONDPAG) )  //FILIAL+CONDICAO PAGTO

        SB1->(DbSetOrder(1))
        SB1->(MsSeek(xFilial("SB1")+SC6->C6_PRODUTO))    //FILIAL+PRODUTO

        SB2->(DbSetOrder(1))
        SB2->(MsSeek(xFilial("SB2")+SC6->(C6_PRODUTO+C6_LOCAL))) //FILIAL+PRODUTO+LOCAL

        SF4->(DbSetOrder(1))
        SF4->(MsSeek(xFilial("SF4")+SC6->C6_TES))   //FILIAL+TES

        nPrcVen := SC9->C9_PRCVEN
        If ( SC5->C5_MOEDA <> 1 )
            nPrcVen := xMoeda(nPrcVen,SC5->C5_MOEDA,1,dDataBase)
        EndIf

        AAdd(aPvlDocS,{ SC9->C9_PEDIDO,;
            SC9->C9_ITEM,;
            SC9->C9_SEQUEN,;
            SC9->C9_QTDLIB,;
            nPrcVen,;
            SC9->C9_PRODUTO,;
            .F.,;
            SC9->(RecNo()),;
            SC5->(RecNo()),;
            SC6->(RecNo()),;
            SE4->(RecNo()),;
            SB1->(RecNo()),;
            SB2->(RecNo()),;
            SF4->(RecNo())})

        SC6->(DbSkip())
    EndDo
    
    cDoc := MaPvlNfs(  /*aPvlNfs*/          aPvlDocS,;  // 01 - Array com os itens a serem gerados
                        /*cSerieNFS*/       cSerie,;    // 02 - SérieSerie da Nota Fiscal
                        /*lMostraCtb*/      .F.,;       // 03 - Mostra LançamentoLancamento ContábilContabil
                        /*lAglutCtb*/       .F.,;       // 04 - Aglutina LançamentoLancamento ContábilContabil
                        /*lCtbOnLine*/      .F.,;       // 05 - Contabiliza On-Line
                        /*lCtbCusto*/       .T.,;       // 06 - Contabiliza Custo On-Line
                        /*lReajuste*/       .F.,;       // 07 - Reajuste de preço na Nota Fiscal
                        /*nCalAcrs*/        0,;         // 08 - Tipo de AcréscimoAcrescimo Financeiro
                        /*nArredPrcLis*/    0,;         // 09 - Tipo de Arredondamento
                        /*lAtuSA7*/         .T.,;       // 10 - Atualiza AmarraçãoAmarracao Cliente x Produto
                        /*lECF*/            .F.,;       // 11 - Cupom Fiscal
                        /*cEmbExp*/         cEmbExp,;   // 12 - Número do Embarque de ExportaçãoExportacao
                        /*bAtuFin*/         {||},;      // 13 - Bloco de CódigoCodigo para complemento de atualizaçãoatualizacao dos títulostitulos financeiros
                        /*bAtuPGerNF*/      {||},;      // 14 - Bloco de CódigoCodigo para complemento de atualizaçãoatualizacao dos dados após a geraçãogeracao da Nota Fiscal
                        /*bAtuPvl*/         {||},;      // 15 - Bloco de CódigoCodigo de atualizaçãoatualizacao do Pedido de Venda antes da geraçãogeracao da Nota Fiscal
                        /*bFatSE1*/         {|| .T. },; // 16 - Bloco de CódigoCodigo para indicar se o valor do TítuloTitulo a Receber serásera gravado no campo F2_VALFAT quando o parâmetro MV_TMSMFAT estiver com o valor igual a "2".
                        /*dDataMoe*/        dDatabase,; // 17 - Data da cotaçãocotacao para conversão dos valores da Moeda do Pedido de Venda para a Moeda Forte
                        /*lJunta*/          .F.)        // 18 - Aglutina Pedido Iguais
    
    If !Empty(cDoc)
        Conout("Documento de Saida: " + cSerie + "-" + cDoc + ", gerado com sucesso!!!")
    EndIf

    RESET ENVIRONMENT

Return .T.