Histórico da Página

#include "protheus.ch"

User Function M486OWSCOL()

	Local cSerieDoc := PARAMIXB[1] //Serie
	Local cNumDoc := PARAMIXB[2] //Numero de Documento
	Local cCodCli := PARAMIXB[3] //Codigo de Cliente
	Local cCodLoj := PARAMIXB[4] //Codigo de la Tienda
	Local oXML := PARAMIXB[5] //Objeto del XML
	Local nOpc := PARAMIXB[6] //Nivel: 1-Encabezado, 2=detalle
	Local oWS := PARAMIXB[7] //Objeto de web services
	Local aEmail := {}
	Local oWSDest := Nil
	Local oWSCta := Nil
	Local nX := 0

	If nOpc == 1 //Encabezado

		// Posicionar cliente
		SA1->(dbSetOrder(1))

		If SA1->(msSeek(xFilial("SA1")+cCodCli+cCodLoj))

			// Como ejemplo se usa el campo A1_PRF_OBS (Comentarios de perfil)
			If !Empty(SA1->A1_PRF_OBS)

				// Las cuentas de correo están separadas por coma
				aEmail := StrTokArr(SA1->A1_PRF_OBS, ",")

				// Indicar Sí notificar
				oWS:oWSCliente:cnotificar := "SI"

				// Crea objeto destinatario, el medio de entrega es 0=email
				oWSDest := Service_Destinatario():NEW()
				oWSDest:ccanalDeEntrega := "0"

				// Crea arreglo de las cuentas de correo
				oWSDest:oWSemail := Service_ArrayOfstring():NEW()

				For nX := 1 to Len(aEmail)

					aAdd(oWSDest:oWSEmail:cstring, aEmail[nX])

				Next nX

				// Agrega destinatario al objeto principal
				aAdd(oWS:oWSCliente:oWSDestinatario:oWSDestinatario, oWSDest)

			EndIf

		EndIf

	EndIf

Return Nil