Histórico da Página

Descrição

Rotina automática para inclusão de lançamentos contábeis no ambiente Contabilidade Gerencial (SIGACTB).

Exemplo

#INCLUDE "PROTHEUS.CH"

//-------------------------------------------------------------------
/*/{Protheus.doc} CargaCT2    

 Programa opções de Execauto do CTBA102

@author Felipe Cunha 
@since 29/11/2013
@version 1.0

/*/
//-------------------------------------------------------------------

User Function CargaCT2()

Local oRegua

Local lEnd := .T.

// --------------------------------------------------------------------------

// Na utilização de execAuto considerar os seguintes critérios:

// 1 - Passar o campo CT2_CONVER como 15555, demais moedas devem ser feitos

//     pela inclusão de um novo aItens

// 2 - na alteração de registro passe novamente o ACab

// --------------------------------------------------------------------------

If MsgYesNo("Deseja realizar a carga dos dados ?")

    oRegua := MsNewProcess():New({|lEnd| GravaCTB(oRegua,@lEnd) },"Processando","",.T.)

    oRegua:Activate()

    MsgAlert("Carga Finalizada")

EndIf

Return

//-------------------------------------------------------------------
/*/{Protheus.doc} GravaCTB   

 Programa inclusão de lançamentos contábeis

@author Felipe Cunha 
@since 29/11/2013
@version 1.0

/*/
//-------------------------------------------------------------------

Static Function GravaCTB(oObj,lEnd)

Local nX

Local aArea         := GetArea()

Local nDoc            := 1

Local lRet            := .T.

Local aCab            := {}

Local aItens        := {}

Local aLinha         := {}

Local dDataLanc     := ctod("28/11/2013")  

Local nLinha        := '001'

Private lMsErroAuto     := .F.

Private lMsHelpAuto     := .T.

Private CTF_LOCK        := 0

Private lSubLote         := .T.

oObj:SetRegua1(5)

oObj:IncRegua1("Gerando Documentos")

oObj:SetRegua1(nDoc)

For nX:=1 To nDoc

    If lEnd

        Exit

    EndIf

    oObj:IncRegua2("Documento " + cValToChar(nX) + " de "+ cValToChar(nDoc))

    aCab := {}

    aItem := {}

   /*-------------------------------------------------------------

    //

ExecAuto de

teste para

inclusão de lançamento  

    //----------------------------------------------------------*/

    aAdd(aCab,  {'DDATALANC'     ,dDataBase        ,NIL} )

    aAdd(aCab,  {'CLOTE'         ,'333333'         ,NIL} )

    aAdd(aCab,  {'CSUBLOTE'         ,'001'         ,NIL} )

    aAdd(aCab,  {'CDOC'             ,'000001'         ,NIL} )

    aAdd(aCab,  {'CPADRAO'         ,''             ,NIL} )

    aAdd(aCab,  {'NTOTINF'         ,0                 ,NIL} )

    aAdd(aCab,  {'NTOTINFLOT'     ,0                 ,NIL} )

    aAdd(aItens,{  {'CT2_FILIAL'      ,'0101   '       , NIL},;

                   {'CT2_LINHA'      , nLinha          , NIL},;

                   {'CT2_MOEDLC'      ,'01'           , NIL},;

                   {'CT2_DC'           ,'3'           , NIL},;

                   {'CT2_DEBITO'      ,'101010100'     , NIL},;

                   {'CT2_CREDIT'      ,'201010100'     , NIL},;

                   {'CT2_VALOR'      , 3000          , NIL},;

                   {'CT2_ORIGEM'     ,'MSEXECAUT'    , NIL},;

                   {'CT2_HP'           ,''               , NIL},;

                   {'CT2_CONVER'    ,'11'         , NIL},;

                   {'CT2_HIST'       ,'MSEXECCT2'    , NIL} } )         

    MSExecAuto({|x, y,z| CTBA102(x,y,z)}, aCab ,aItens, 3)

    /*-------------------------------------------------------------

    // ExecAuto de teste da atualização de

lançamento  

    //----------------------------------------------------------*/

    aCab     := {}

    aItens     := {}

    aLinha := {}

    aAdd(aCab,  {'DDATALANC'     ,dDataBase        ,NIL} )

    aAdd(aCab,  {'CLOTE'         ,'333333'         ,NIL} )

    aAdd(aCab,  {'CSUBLOTE'         ,'001'         ,NIL} )

    aAdd(aCab,  {'CDOC'             ,'000001'         ,NIL} )

    aAdd(aCab,  {'CPADRAO'         ,''             ,NIL} )

    aAdd(aCab,  {'NTOTINF'         ,0                 ,NIL} )

    aAdd(aCab,  {'NTOTINFLOT'     ,0                 ,NIL} )

    aAdd(aItens,{      {'CT2_FILIAL'      ,'0101   '           , NIL},;

                       {'CT2_LINHA'      , nLinha              , NIL},;

                       {'CT2_MOEDLC'      ,'01'               , NIL},;

                       {'CT2_DC'          ,'3'               , NIL},;

                       {'CT2_DEBITO'      ,'101010100'         , NIL},;

                       {'CT2_CREDIT'      ,'201010100'         , NIL},;

                       {'CT2_VALOR'      , 6000              , NIL},;

                       {'CT2_ORIGEM'     ,'MSEXECAUT'        , NIL},;

                       {'CT2_HP'          ,''                   , NIL},;

                       {'CT2_EMPORI'     ,'01'                 , NIL},;

                       {'CT2_FILORI'      ,'0101001'            , NIL},;                       

                       {'CT2_HIST'       ,'MSEXECCT2-1'    , NIL},;

                       {'LINPOS'            ,'CT2_LINHA'        ,nLinha}})  

    MSExecAuto({|x, y,z| CTBA102(x,y,z)}, aCab ,aItens, 4)

    If lMsErroAuto

        lMsErroAuto := .F.

        MsgAlert("ERRO Lançamento" , "Teste Carga CT2")

        lRet := .F.

        Exit

    Endif

Next nX

cFileLog := NomeAutoLog()

cPath := ""

If !Empty(cFileLog) .And. !lRet

    MostraErro(cPath,cFileLog)

Endif

RestArea(aArea)

Return

Idioma

Português(Brasil)

Versões

Microsiga_Protheus10_e_Microsiga_Protheus11

Sistemas Operacionais Suportados

Todos

Compatível com as Bases de Dados

Todas

Programa Fonte

CTBA102.PRW