O ponto de entrada irá efetuar os seguintes procedimentos: Linha 25: se o cálculo da provisão está entre o período inicial e período final do adiamento do 1/3 de férias; Linha 27: se o período estiver em aberto, efetua busca na tabela SRC para verba de quitação do 1/3 de férias adiado, ou se o período estiver fechado, efetua a busca na tabela SRD. Se encontrar a verba, significa que não é necessário retornar o saldo de 1/3 de férias; Linha 4035: se precisa retornar o saldo de 1/3 de férias e encontrar cálculo de férias para o funcionário na tabela SRH; Linha 4237: percorre todos os registros da tabela SRH para o funcionário; Linha 4439: se o cálculo de férias iniciou entre o período inicial e período final do adiamento do 1/3 de férias; Linha 4641: se encontrou na tabela SRR pela verba de base de 1/3 de férias; Linha 4843: percorre todos os registros da tabela SRR da verba de base de 1/3 de férias para o funcionário Linha 4944: pega o valor da verba através do campo RR_VALOR; Linha 5045: adiciona o valor da verba encontrada na posição do Array de férias vencidas correspondente ao saldo atual de 1/3 de férias; Linha 5146: adiciona o valor de INSS correspondente a verba encontrada na posição do Array de férias vencidas correspondente ao saldo atual de INSS; Linha 5247: adiciona o valor de FGTS correspondente a verba encontrada na posição do Array de férias vencidas correspondente ao saldo atual de FGTS; Linha 5348: adiciona o valor de PIS correspondente a verba encontrada na posição do Array de férias vencidas correspondente ao saldo atual de PIS; Linha 5853: se encontrou na tabela SRR pela verba de base de 1/3 de férias; Linha 6055: percorre todos os registros da tabela SRR da verba de base de 1/3 de férias mês seguinte para o funcionário Linha 6156: pega o valor da verba através do campo RR_VALOR; Linha 6257: adiciona o valor da verba encontrada na posição do Array de férias vencidas correspondente ao saldo atual de 1/3 de férias; Linha 6358: adiciona o valor de INSS correspondente a verba encontrada na posição do Array de férias vencidas correspondente ao saldo atual de INSS; Linha 6459: adiciona o valor de FGTS correspondente a verba encontrada na posição do Array de férias vencidas correspondente ao saldo atual de FGTS; Linha 6560: adiciona o valor de PIS correspondente a verba encontrada na posição do Array de férias vencidas correspondente ao saldo atual de PIS;
| Bloco de código |
|---|
| theme | Emacs |
|---|
| firstline | 9 |
|---|
| linenumbers | true |
|---|
| //Ponto de entrada para alterar o valor provisionado de férias vencidas para retornar o valor de 1/3 para o saldo
User Function GP070P13()
Local aAreaSRC := SRC->( GetArea() )
Local aAreaSRD := SRD->( GetArea() )
Local aAreaSRH := SRH->( GetArea() )
Local aAreaSRR := SRR->( GetArea() )
Local lProvUmT := .T.
Local nValUmT := 0
SRC->( dbSetOrder(1) )//RC_FILIAL+RC_MAT+RC_PD+RC_CC+RC_SEMANA+RC_SEQ
SRD->( dbSetOrder(1) )//RD_FILIAL+RD_MAT+RD_DATARQ+RD_PD+RD_SEMANA+RD_SEQ+RD_CC+RD_PROCES
SRH->( dbSetOrder(1) )//RH_FILIAL+RH_MAT+DTOS(RH_DATABAS)+DTOS(RH_DATAINI)
SRR->( dbSetOrder(1) )//RR_FILIAL+RR_MAT+RR_TIPO3+DTOS(RR_DATA)+RR_PD+RR_CC+RR_PROCES
//Se o cálculo da provisão estiver dentro do período do adiamento do 1/3
If cAnoMes >= cPIniMP927 .And. cAnoMes <= cPFimMP927
//Se o período estiver aberto
If !Empty(aPerAberto)
//Pesquisa na tabela SRC a verba de pagamento do 1/3 adiado
If SRC->( dbSeek(SRA->RA_FILIAL + SRA->RA_MAT + cVbUmTFol) )
.And. SRC->RC_PERIODO == cAnoMes
lProvUmT := .F.
EndIf
//Se o período estiver fechado
Else
//Pesquisa na tabela SRD a verba de pagamento do 1/3 adiado
If SRD->( dbSeek(SRA->RA_FILIAL + SRA->RA_MAT + cAnoMes + cVbUmTFol) )
lProvUmT := .F.
EndIf
EndIf
//Se não houve pagamento do 1/3 adiado realiza busca na tabela SRH para verificar se o funcionário possui férias calculadas
If lProvUmT .And. SRH->( dbSeek(SRA->RA_FILIAL + SRA->RA_MAT) )
//Pesquisa por todos os registros existentes na tabela SRH para o funcionário
While SRH->( !Eof() ) .And. SRA->RA_FILIAL+SRA->RA_MAT == SRH->RH_FILIAL+SRH->RH_MAT
//Se o cálculo das férias estiver dentro do período do adiamento do 1/3
If AnoMes(SRH->RH_DATAINI) >= cPIniMP927 .And. AnoMes(SRH->RH_DATAINI) <= cPFimMP927
//Pesquisa nas verbas calculadas nas férias do funcionário pela verba de base de 1/3
If SRR->( dbSeek(SRA->RA_FILIAL + SRA->RA_MAT + "F" + dToS(SRH->RH_DATAINI) + cVbUmTFer ) )
//Pesquisa por todos os registros existentes na tabela SRR para o funcionário referente à verba de base de 1/3
While SRR->( !Eof() ) .And. SRA->RA_FILIAL+SRA->RA_MAT+"F"+dToS(SRH->RH_DATAINI)+cVbUmTFer == SRR->RR_FILIAL+SRR->RR_MAT+SRR->RR_TIPO3+dToS(SRR->RR_DATA)+SRR->RR_PD
nValUmT := SRR->RR_VALOR
aFerVenc[_Atual,_1Ter] += nValUmT//1/3 de férias
aFerVenc[_Atual,_INSS] += NoRound(nValUmT * (nPercEmp+nPercTer+nPercAcTrab))//INSS
aFerVenc[_Atual,_FGTS] += NoRound(nValUmT * nPercFgts)//FGTS
aFerVenc[_Atual,_PIS] += NoRound(nValUmT * nPercPis)//PIS
SRR->( dbSkip() )
End
EndIf
//Pesquisa nas verbas calculadas nas férias do funcionário pela verba de base de 1/3 mês seguinte
If SRR->( dbSeek(SRA->RA_FILIAL + SRA->RA_MAT + "F" + dToS(SRH->RH_DATAINI) + cVbUmTFMS ) )
//Pesquisa por todos os registros existentes na tabela SRR para o funcionário referente à verba de base de 1/3
While SRR->( !Eof() ) .And. SRA->RA_FILIAL+SRA->RA_MAT+"F"+dToS(SRH->RH_DATAINI)+cVbUmTFMS == SRR->RR_FILIAL+SRR->RR_MAT+SRR->RR_TIPO3+dToS(SRR->RR_DATA)+SRR->RR_PD
nValUmT := SRR->RR_VALOR
aFerVenc[_Atual,_1Ter] += nValUmT//1/3 de férias
aFerVenc[_Atual,_INSS] += NoRound(nValUmT * (nPercEmp+nPercTer+nPercAcTrab))//INSS
aFerVenc[_Atual,_FGTS] += NoRound(nValUmT * nPercFgts)//FGTS
aFerVenc[_Atual,_PIS] += NoRound(nValUmT * nPercPis)//PIS
SRR->( dbSkip() )
End
EndIf
EndIf
SRH->( dbSkip() )
End
EndIf
EndIf
RestArea( aAreaSRC )
RestArea( aAreaSRD )
RestArea( aAreaSRH )
RestArea( aAreaSRR )
Return |
| 