Histórico da Página

#Include 'Totvs.ch'

//-------------------------------------------------------------------
/*/{Protheus.doc} MNT655EXEC
ExecAuto MNTA655
/*/
//-------------------------------------------------------------------
User Function MNT655EXEC()

	//------------------------------------------
	// Processo de Inclusão
	//------------------------------------------
	Local aAbast := {}

	//Abre empresa/filial/modulo/arquivos
	RPCSetEnv('Código da empresa','Código da filial','','','Código do módulo')

	// Itens obrigatórios para inclusão do abastecimento para posto interno
	aAbast := { {'TQN_PLACA' , 'CGZ-1500'            , Nil },;
				{'TQN_FROTA' , 'CG150           '    , Nil },;
				{'TQN_CNPJ'  , '47467235000151'      , Nil },;
				{'TQN_CODCOM', 'GAS'                 , Nil },;
				{'TQN_DTABAS', StoD( '20191210' )    , Nil },;
				{'TQN_HRABAS', '15:05'               , Nil },;
				{'TQN_TANQUE', '01    '              , Nil },;
				{'TQN_BOMBA' , '01 '                 , Nil },;
				{'TQN_QUANT' , 10                    , Nil },;
				{'TQN_VALUNI', 4                     , Nil },;
				{'TQN_VALTOT', 40                    , Nil },;
				{'TQN_HODOM' , 130                   , Nil },;
				{'TQN_CODMOT', '000001'              , Nil },;
				{'TQN_POSTO' , '099                 ', Nil },;
				{'TQN_LOJA'  , '01  '                , Nil },;
				{'TQN_NOTFIS', '8875137'             , Nil }}

	lMSHelpAuto := .T. // Não apresenta erro em tela
	lMSErroAuto := .F. // Caso a variável torne-se .T. apos MsExecAuto, apresenta erro em tela
	
	MSExecAuto( { | v, x, y | MNTA655( v, x, y ) }, , aAbast, 3 )
	If lMsErroAuto
		If !IsBlind()
			MostraErro()
		Else
			cError := MostraErro( GetSrvProfString("Startpath","") , ) // Armazena mensagem de erro na raízraiz.
			ConOut( cError)
		EndIf
	EndIf
	
	If !lMsErroAuto
		//------------------------------------------
		// Processo de Alteração
		//------------------------------------------
		aAbast := {}

		// Para alteração será necessário informar os campos TQN_FROTA, TQN_DTABAS, TQN_HRABAS para encontrar o abastecimento, os demais campos informados serão referentes as alterações solicitadas
		aAbast := { { 'TQN_FROTA' , 'CG150           ', Nil },;
					{ 'TQN_DTABAS', StoD( '20191210' ), Nil },;
					{ 'TQN_HRABAS', '15:05'           , Nil },;
					{ 'TQN_QUANT' , 5                 , Nil },;
					{ 'TQN_VALUNI', 4                 , Nil },;
					{ 'TQN_VALTOT', 20                , Nil }}


		lMSHelpAuto := .T. // Não apresenta erro em tela
		lMSErroAuto := .F. // Caso a variável torne-se .T. apos MsExecAuto, apresenta erro em tela
		
		MSExecAuto( { | v, x, y | MNTA655( v, x, y ) }, , aAbast, 4 )
		If lMsErroAuto
			If !IsBlind()
				MostraErro()
			Else
				cError := MostraErro( GetSrvProfString("Startpath","") , ) // Armazena mensagem de erro na raízraiz.
				ConOut( cError)
			EndIf
		EndIf
	EndIf
	
	If !lMsErroAuto
		//------------------------------------------
		// Processo de Exclusão
		//------------------------------------------
		aAbast := {}

		// Para alteração será necessário informar os campos TQN_FROTA, TQN_DTABAS, TQN_HRABAS para encontrar o abastecimento.
		aAbast := { { 'TQN_FROTA' , 'CG150           ', Nil },;
					{ 'TQN_DTABAS', StoD( '20191210' ), Nil },;
					{ 'TQN_HRABAS', '15:05'           , Nil }}

		lMSHelpAuto := .T. // Não apresenta erro em tela
		lMSErroAuto := .F. // Caso a variável torne-se .T. apos MsExecAuto, apresenta erro em tela
		
		MSExecAuto( { | v, x, y | MNTA655( v, x, y ) }, , aAbast, 5 )

		If lMsErroAuto
			If !IsBlind()
				MostraErro()
			Else
				cError := MostraErro( GetSrvProfString("Startpath","") , ) // Armazena mensagem de erro na raiz.
				ConOut( cError)
			EndIf
		EndIf
	EndIf

Return