TOTVSTEC

Árvore de páginas

Indica o token OAuth2 que será utilizado no envio e recebimento de e-mails.

Tipo

Valor Padrão

Somente Leitura

caractere

""

N

Observações

  • Essa propriedade deve ser definida antes de chamar os métodos de connect (SMTPConnect ou Connect).
  • Essa propriedade impacta o recebimento e o envio de emails.
  • O token (Access Token) deve ser gerado através de ferramenta externa à classe.
  • Se a conexão utilizada for usando o protocolo MAPI, o método não tem efeito.

Exemplos

user function tstgmail()
  Local cServer     := "imap.gmail.com"
  Local nServerPort := 993
  // Local cServer     := "pop.gmail.com"
  // Local nServerPort := 995
  Local cSMTP       := "smtp.gmail.com"
  Local nSMTPPort   := 587
  Local cUser       :=  "[email protected]" //Usuário com @gmail.com
  Local cToken      := "access_token"
  Local cPass       :=  "password"
  Local oSrv        := TMailMng():New( 1, 6, 6 )     //IMAP
  // Local oSrv        := TMailMng():New( 0, 6, 6 )  //POP
  Local oMsg        := TMailMessage():New()
  Local nTimeout    := 60
  Local nMessages   := 0
  Local xRet
  
  oSrv:cUser := cUser
  oSrv:cPass := cPass
  
  oSrv:cSrvAddr := cServer
  oSrv:nSrvPort := nServerPort
  oSrv:nSrvTimeout := nTimeout
  
  oSrv:cSMTPAddr := cSMTP
  oSrv:nSMTPPort := nSMTPPort
  oSrv:nSMTPTimeout := nTimeout
  
  oSrv:cOAuthToken := cToken
  
  xRet := oSrv:SMTPConnect()
  if xRet <> 0
    conout( "Erro SMTPConnect oSrv: " + oSrv:GetErrorString( xRet ) )
    return
  endif
  
  xRet := oSrv:SMTPAuth( cUser, cPass )
  if xRet <> 0
    conout( "Erro SMTPAuth oSrv: " + oSrv:GetErrorString( xRet ) )
    return
  endif
  
  oMsg:Clear()
  oMsg:cDate      := cValToChar( Date() )
  oMsg:cTo        := "[email protected]"
  oMsg:cSubject   := "Test - Acentuação - B.i - sofá; crachá; parabéns; jacarés; açaí; Piauí;"
  oMsg:MsgBodyType( "text/plain" )
  oMsg:MsgBodyEncode( 1 )
  oMsg:cBody      := "Test"
  
  xRet := oMsg:Send2( oSrv )
  if xRet <> 0
    conout( "Erro Send oSrv: " + oSrv:GetErrorString( xRet ) )
    return
  endif
  
  conout( "Email enviado" )
  
  xRet := oSrv:SMTPDisconnect()
  if xRet <> 0
    conout( "Erro SmtpDisconnect: " + oSrv:GetErrorString( xRet ) )
    return
  endif
  
  conout( "Disconectado SMTP" )
  
  oMsg:Clear()
  
  xRet := oSrv:Connect()
  if xRet <> 0
    conout( "Erro Connect oSrv: " + oSrv:GetErrorString( xRet ) )
    return
  endif
  
  oSrv:GetNumMsgs( @nMessages )
  
  if nMessages > 0
    conout( "GetNumMsgs: " + cValToChar( nMessages ) )
    xRet := oMsg:Receive2( oSrv, 1 )
    if xRet <> 0
      conout( "Erro Receive oSrv: " + oSrv:GetErrorString( xRet ) )
    else
      conout( "   Date: " + oMsg:cDate )
      conout( "   From: " + oMsg:cFrom )
      conout( "     To: " + oMsg:cTo )
      conout( "Subject: " + oMsg:cSubject )
      // conout( "   Body: " + oMsg:cBody )
    endif
  endif
  
  xRet := oSrv:Disconnect()
  if xRet <> 0
    conout( "Erro Disconnect oSrv: " + oSrv:GetErrorString( xRet ) )
    return
  endif
  
  conout( "Disconnect Sucesso!!!" )
return

Abrangência

A propriedade está disponível a partir da versão 20.3.0.14 do Application Server.

Veja também

  • Sem rótulos