FwStruTrigger

FwStruTrigger(<cDom >, <cCDom >, <cRegra >, [ lSeek ], <cAlias >, [ nOrdem ], [ cChave ], [ cCondic ], [ cSequen ])-> aRetorno

A função fornece um array com a estrutura para criação de um trigger na estrutura de dados de um submodelo (FWFormModelStruct).
Ela deve ser usada quando deseja-se criar um gatilho na estrutura de dados, baseado nos parametros informados
a função devolve as informações que são necessárias para criar um gatilho usando o método AddTrigger.

 

aRetorno Array com a definição dos gatilhos que serão utilizado pela FWFormModelStruct
[01] ExpC:IdField Origem
[02] ExpC:IdField Alvo
[03] ExpB:When
[04] ExpB:Execução

Static Function ModelDef()
Local oModel := MPFormModel():New("TESTE")
Local oStru := FWFormStruct(1, "ZA1")
Local aAux := CreateTrigger()

oStru:AddTrigger( ;
      aAux[1] , ;       // [01] Id do campo de origem
      aAux[2] , ;       // [02] Id do campo de destino
      aAux[3] , ;       // [03] Bloco de codigo de validação da execução do gatilho
      aAux[4] )       // [04] Bloco de codigo de execução do gatilho

Return oModel

Static Function CreateTrigger()
Local aAux :=   FwStruTrigger(;
      "XZ1_SOURCE" ,; // Campo Dominio
      "XZ1_SOURCE" ,; // Campo de Contradominio
      "CFG600G01('XZ1_SOURCE',M->XZ1_SOURCE)",; // Regra de Preenchimento
      .F. ,; // Se posicionara ou nao antes da execucao do gatilhos
      "" ,; // Alias da tabela a ser posicionada
      0 ,; // Ordem da tabela a ser posicionada
      "" ,; // Chave de busca da tabela a ser posicionada
      NIL ,; // Condicao para execucao do gatilho
      "01" ) // Sequencia do gatilho (usado para identificacao no caso de erro)   
Return aAux