Viagens - Financeiro - P12

01. VISÃO GERAL

Um funcionário (neste cenário, o chamamos de Participante) necessita fazer uma viagem corporativa, por algum motivo, seja ele qual for (ex: atendimento/visita ao cliente, reunião de negócios, evento). Então esta rotina terá como principal objetivo registrar a solicitação dessa viagem, contemplando informações relevantes para controlar as despesas da viagem e suas políticas.

Nos itens da viagem será possível selecionar e justificar/detalhar os seguintes serviços:

• Vôo
• Hotel
• Carro
• Rodoviário
• Seguros
• Outros

Quando parametrizadas para aprovação após a solicitação, será gerada uma pendência de aprovação para o superior dos participantes. Caso contrário esta pode ser enviada para o departamento de viagens (diretamente após a solicitação ou em um segundo momento através da opção de envio) e a viagem será gerada automaticamente.

Exemplo:

A empresa pode decidir por passar por todas as aprovações, neste caso o fluxo será:

Ou então pode ser que apenas uma das aprovações seja necessária, neste caso temos:

02. EXEMPLO DE UTILIZAÇÃO

Acesso à rotina pelo caminho: Atualizações > Viagens > Solicitação de Viagem

O viajante deve informar os dados básicos da viagem no cabeçalho da sua solicitação, como origem e destino, datas de partida e chegada, cliente para atendimento (se houver), etc.
Para cada serviço deve ser informado o(s) Participante(s) e a(s) sua(s) respectiva(s) Entidade(s) de Custo.



Além disso, na aba Adiantamentos é possível marcar quais participantes receberão adiantamento.

O valor calculado é uma previsão e é exibido somente quando estiver parametrizado:

03. ROTINA AUTOMÁTICA

Para execução da rotina automática, ilustramos algumas funcionalidades como Inclusão (MyFA666Inc), Alteração (MyFA666Alt) e Exclusão (MyFA666Del), nos seguintes exemplos:

#INCLUDE "PROTHEUS.CH"
#INCLUDE "FWMVCDEF.CH"

//---------- Inclusao da solicitacao de viagem ----------//
User Function MyFA666Inc()

Local oModel := Nil
Local oModelFW3 := Nil
Local oModelFW4 := Nil
Local oModelFW5 := Nil
Local oModelFW6 := Nil
Local cFilAtu := ""

RpcSetEnv("T1","D MG 01 ","claudio.ribeiro","1") // Inicializa ambiente com usuario solicitante

oModel := FWLoadModel("FINA666")
oModelFW3 := oModel:GetModel("FW3MASTER") // Cabecalho da viagem
oModelFW4 := oModel:GetModel("FW4DETAIL") // Servicos 
oModelFW5 := oModel:GetModel("FW5DETAIL") // Participantes
oModelFW6 := oModel:GetModel("FW6DETAIL") // Centro de custo
cFilAtu := xFilial("FW3")

oModel:SetOperation(MODEL_OPERATION_INSERT)
oModel:Activate()
// Preenche cabecalho da solicitacao de viagem
oModelFW3:SetValue("FW3_FILIAL",cFilAtu)
oModelFW3:SetValue("FW3_NACION","1")
oModelFW3:SetValue("FW3_CODORI","SP")
oModelFW3:SetValue("FW3_CODDES","RJ")
oModelFW3:SetValue("FW3_DTINI",StoD("20190702"))
oModelFW3:SetValue("FW3_DTFIM",StoD("20190705"))
oModelFW3:SetValue("FW3_CLIENT","001 ")
oModelFW3:SetValue("FW3_LOJA","01")
oModelFW3:SetValue("FW3_STATUS","0") // Em Aberto, status inicial
// Preenche grid do servico incluso na solicitacao da viagem
oModelFW4:SetValue("FW4_ITEM",StrZero(1,TamSX3("FW4_ITEM")[1]))
oModelFW4:SetValue("FW4_TIPO","1") // Aereo
oModelFW4:SetValue("FW4_OBS", "Visita ao cliente")
// Preenche grid dos participantes viajantes
oModelFW5:SetValue("FW5_ITEM",StrZero(1,TamSX3("FW4_ITEM")[1]))
oModelFW5:SetValue("FW5_PARTIC","000001")
oModelFW5:SetValue("FW5_ADIANT",.T.) // Adiciona adiantamento ao participante
oModelFW5:AddLine() // Adiciona linha para um segundo viajante
oModelFW5:SetValue("FW5_ITEM",StrZero(2,TamSX3("FW4_ITEM")[1]))
oModelFW5:SetValue("FW5_PARTIC","000002")
oModelFW5:SetValue("FW5_ADIANT",.T.) // Adiciona adiantamento ao participante
// Preenche grid do centro de custo
oModelFW6:SetValue("FW6_ITEM",StrZero(1,TamSX3("FW4_ITEM")[1]))
oModelFW6:SetValue("FW6_CC","002 ")
oModelFW6:SetValue("FW6_PORCEN",100)
oModelFW5:GoLine(1)
// Validacao e gravacao dos dados se consistentes
If oModel:VldData() 
     oModel:CommitData()
     Conout("Inclusao da solicitacao de viagem concluida com sucesso.")
Else 
     VarInfo("",oModel:GetErrorMessage())
     Conout("Erro na validacao, solicitacao de viagem nao foi incluida.")
EndIf

oModel:DeActivate()
oModel:Destroy()
RpcClearEnv()

Return


//---------- Alteracao da solicitacao de viagem ----------//
User Function MyFA666Alt()

Local aKeyFW4 := {}
Local oModel := Nil
Local oModelFW5 := Nil
Local oModelFW6 := Nil
Local cSolic := "0000000010"

RpcSetEnv("T1","D MG 01 ","richard.santos","1") // Inicializa ambiente com usuario solicitante

dbSelectArea("FW3")
dbSetOrder(1)
dbSeek(xFilial("FW3")+cSolic)
// Carrega modelo de dados com a solicitacao de viagem posicionada
oModel := FWLoadModel("FINA666")
oModelFW5 := oModel:GetModel("FW5DETAIL") // Participantes
oModelFW6 := oModel:GetModel("FW6DETAIL") // Centro de custo
// Chave de busca do participante dentro da sol. da viagem
aKeyFW4 := { {"FW5_FILIAL",xFilial("FW5")},{"FW5_SOLICI",cSolic},{"FW5_ITEM","01"},{"FW5_PARTIC","000002"} }

oModel:SetOperation(MODEL_OPERATION_UPDATE)
oModel:Activate()
// Remove um dos viajantes, no caso o participante 000002
If oModelFW5:SeekLine(aKeyFLE)
     oModelFW5:DeleteLine()
Else
     Conout("Viajante nao encontrado nesta solicitacao de viagem.")
EndIf
// Altera o centro de custo (posicionado automaticamente no primeiro grid)
oModelFW6:SetValue("FW6_CC","003 ")

// Validacao e gravacao dos dados se consistentes
If oModel:VldData() 
     oModel:CommitData()
     Conout("Alteracao da solicitacao de viagem efetuada com sucesso.")
Else 
     VarInfo("",oModel:GetErrorMessage())
     Conout("Erro na validacao, solicitacao de viagem nao foi alterada.")
EndIf

oModel:DeActivate()
oModel:Destroy()
RpcClearEnv()

Return


//---------- Exclusao da solicitacao de viagem ----------//
User Function MyFA666Del()

Local oModel := Nil
Local cSolic := "0000000010"

RpcSetEnv("T1","D MG 01 ","claudio.ribeiro","1") // Inicializa ambiente com usuario solicitante

dbSelectArea("FW3")
dbSetOrder(1)
dbSeek(xFilial("FW3")+cSolic)
// Carrega modelo de dados com a solicitacao de viagem posicionada
oModel:= FWLoadModel("FINA666")
oModel:SetOperation(MODEL_OPERATION_DELETE)
oModel:Activate()

// Validacao e gravacao da exclusao
If oModel:VldData() 
     oModel:CommitData()
     Conout("Solicitacao de viagem excluida com sucesso.")
Else 
     VarInfo("",oModel:GetErrorMessage())
     Conout("Erro na validacao, solicitacao de viagem nao foi excluida.")
EndIf

oModel:DeActivate()
oModel:Destroy()
RpcClearEnv()

Return

04. TABELAS UTILIZADAS

• FW3 - Cabeçalho da Solicitação
• FW4 - Serviços (itens)
• FW5 - Participantes
• FW6 - Entidades de Custos

A rotina de Viagens (FINA665) possui todas as informações relacionadas às viagens já emitidas via agência ou solicitação de viagem avulsa.

Uma viagem é composta por:

Cabeçalho da viagem, que possui os dados de data de início e fim, origem e destino, cliente a ser atendido (quando aplicável) etc.

Na aba adiantamentos são listados os participantes e os adiantamentos solicitados para cada um deles.

Na aba da viagem propriamente dita temos a listagem de todos os pedidos efetuados.

Ao selecionar um item de pedido da viagem, é habilitado um contexto por serviço com os dados específicos de cada um deles, como por exemplo: Para vôo temos a Cia. Aérea, Localizador, Classe etc.; no caso de um hotel temos o Nome do Hotel, datas de check-in e check-out etc. O serviços possíveis são:

• Vôo
• Hotel
• Carro
• Rodoviário
• Seguros
• Outros

São exibidos também os Participantes e as Entidades de Custo relacionadas.

Uma viagem efetuada no Reserve, é integrada somente quando está emitida, ou seja, não é possível alterar os seus serviços no Protheus (datas, valores etc). Os únicos dados passíveis de edição são as Entidades de Custo. Para mais detalhes, consulte o manual da integração TOTVS X Reserve.

Já uma viagem gerada de uma Solicitação de Viagens do Protheus, deve ter os seus detalhes de serviços informados pelo departamento de viagens através da opção de Conferência, já que a solicitação é um pedido para a compra da viagem. Caso a aprovação esteja habilitada após a conferência, será gerada um pendência de aprovação para o superior dos participantes.

Uma viagem com todos os seus serviços e gastos devidamente pagos e prestado contas é elegível para faturamento. Este processo exibe os custos da viagem que podem ser repassados para o cliente, integral ou parcialmente, e gera um pedido de venda para o cliente. Caso não seja aplicável para o segmento da empresa, este passo não é obrigatório.

01. VISÃO GERAL

Os Adiantamentos (FINA667) são os valores creditados aos colaboradores para cobrir os gastos de uma viagem, tais como alimentação, transporte, comunicação etc.

Estes valores são calculados através da configuração da política de viagens da empresa, podendo ser:

1. Valor Fixo: Este é o valor fixo concedido, normalmente para o valor de traslado.
2. Valor com e sem Pernoite: Quando a viagem possui período dentro do mesmo dia, é calculado o valor do adiantamento sem pernoite, caso extrapole uma diária, será calculado com o valor com pernoite
3. Outras moedas: Os valores em outras moedas são normalmente concedidos mediante crédito em traveller check ou compra de moeda. Para este caso o Protheus não faz o cálculo, mas o valor do crédito deste adiantamento deve ser informado. As taxas de conversão da compra desta moeda para a moeda forte podem ser informadas antes ou depois da geração do título mediante configuração no Assistente de Configuração.

Na rotina de Viagens (FINA665) ainda é possível solicitar complementos de adiantamentos. Caso um colaborador precise de mais dinheiro em uma viagem, esta solicitação pode ser efetuada selecionando a viagem e a opção Adiantamento Avulso. Neste caso é gerado mais um adiantamento vinculado à viagem.

As regras de geração de título, tais como Prefixo, Natureza, Data de Vencimento para adiantamentos normais e urgentes (aqueles solicitados fora da regra da política de antecedência) estão no Assistente de Configuração.

Os adiantamentos solicitados tanto via Reserve, Solicitação de Viagens ou Avulso não são aprovados em conjunto com a viagem e geram uma pendência para o superior do viajante, se configurado.

Exemplo:

Se for necessária a aprovação do superior e avaliação financeira, temos:

Ou então teremos os seguintes cenários se uma etapa puder ser realizada automaticamente:

02. EXEMPLO DE UTILIZAÇÃO

O adiantamento pode ser gerado à partir da solicitação de viagem (FINA666), selecionando esta opção na aba Adiantamentos:

O campo RD0_DVIAGE é de uso exclusivo para a integração do RESERVE e que está descontinuado.

Ao clicar no campo adiantamento para o participante, o a adiantamento somente será solicitado se o cadastro do participante estiver com o campo Adiantamento "SIM". Esse controle será feito através do campo RD0_PERMAD (Cadastro de Pessoas).

Se o campo RD0_PERMAD estiver com o valor igual a "Não", o sistema irá mostrar tela de help, conforme abaixo e não permitirá e inclusão do adiantamento para o participante.

Mesmo com a adiantamento bloqueado pelo sistema para adiantamento ao participante na inclusão de viagnes, o sistema não bloqueará a prestação de contas se houver necessidade para esse praticante.

 

Ou após a Viagem já ter sido enviada para o departamento de viagens (FINA665), clicando no botão "Solic. Adiant." e selecionando os participantes que receberão o adiantamento:



Então, através da rotina FINA667, o adiantamento pode ser visualizado, e seguir seu fluxo de ações:

03. ROTINA AUTOMÁTICA

Para execução da rotina automática, ilustramos a solicitação do adiantamento após a efetivação da viagem (MyFA667A), no seguinte exemplo:

#INCLUDE "PROTHEUS.CH"
#INCLUDE "FWMVCDEF.CH"

//---------- Solicitacao de adiantamento da viagem ----------//
User Function MyFA667A()

Local aKeyFLC := {}
Local aUser := {}
Local oModel := Nil
Local oModelFLC := Nil
Local oModelFLD := Nil
Local cViagem := "0000000001"
Local cPartic := "000002"

RpcSetEnv("T1","D MG 01 ","claudio.ribeiro","1") // Inicializa ambiente com usuario solicitante

dbSelectArea("FL5")
dbSetOrder(1)
dbSeek(xFilial("FL5")+cViagem) // Viagem ja solicitada

// Carrega modelo de dados com a solicitacao de viagem posicionada
oModel := FWLoadModel("FINA667A")
oModelFLC := oModel:GetModel("FLCDETAIL") // Participantes
oModelFLD := oModel:GetModel("FLDDETAIL") // Adiantamentos
// Chave de busca do participante dentro da da viagem
aKeyFLC := { {"FLC_FILIAL",xFilial("FLC")},{"FLC_VIAGEM",cViagem},{"FLC_PARTIC",cPartic} }

oModel:SetOperation(MODEL_OPERATION_UPDATE)
oModel:Activate()
If FINXUser(RetCodUsr(),aUser,.T.)
     // Participante que recebera adiantamento
     If oModelFLC:SeekLine(aKeyFLC)
          oModelFLC:SetValue("OK",.T.)
          oModelFLD:LoadValue("FLD_DTSOLI",dDatabase)
          oModelFLD:LoadValue("FLD_DTPREV",DataValida(dDatabase+3))
          oModelFLD:LoadValue("FLD_SOLIC" ,aUser[1])
          oModelFLD:LoadValue("FLD_NOMESO",PadR(aUser[2],TamSx3("FLD_NOMESO")[1]))
          oModelFLD:SetValue("FLD_VALOR",400)
          oModelFLD:SetValue("FLD_MOEDA","1")
          oModelFLD:SetValue("FLD_JUSTIF","Adiantamento para viajante")
          // Validacao e gravacao dos dados se consistentes
          If oModel:VldData()
               oModel:CommitData()
               Conout("Adiantamento solicitado com sucesso.")
          Else 
               VarInfo("",oModel:GetErrorMessage())
               Conout("Erro na validacao, adiantamento nao foi solicitado.")
         EndIf
     Else
          Conout("Viajante nao encontrado nessa viagem.")
     EndIf
EndIf

oModel:DeActivate()
oModel:Destroy()
RpcClearEnv()

Return

04. TABELAS UTILIZADAS

• FL5 - Viagem
• FLC - Passageiros
• FLD - Adiantamentos

Com uma viagem em andamento ou após a sua conclusão, o viajante deve efetuar sua prestação de contas das despesas para a empresa.

Toda viagem, independente de possuir ou não um adiantamento, gera automaticamente um registro na rotina de Prestação de Contas (FINA677) vinculada à ela.

Uma prestação de contas possui os dados básicos de uma viagem, como o seu número, data de início e fim, local, cliente que foi atendido (se for aplicável), além das entidades de custo e percentual de faturamento contra o cliente (se o cliente for aplicável) etc.

O colaborador poderá informar item à item, os gastos que teve em sua viagem informando: despesa, local, valor (na moeda corrente ou em outra e sua taxa de conversão), quantidade, entidades de custos etc.

Além disso, os adiantamentos são listados na prestação de contas e abatidos do valor total no rodapé da prestação de contas.

Os valores gastos, os reembolsáveis e o saldo também são exibidos no rodapé, nas 3 moedas tratadas pelo Protheus: corrente, dólar e euro.

Uma vez finalizada e encaminhada para o departamento de viagens (após sua inclusão ou em momento posterior pela opção de envio para conferência), o departamento de viagens fará a conferência da prestação. Apesar do sistema já efetuar os cálculos dos valores reembolsáveis dos gastos através da regra de limites das despesas, se o conferente identificar algum item nos comprovantes que estão fora da política de viagens, o mesmo pode lançar os descontos neste momento e o valor a ser devolvido/reembolsado é atualizado.

Caso os passos de aprovação e/ou liberação para financeiro estejam ativos, serão geradas pendências para o superior do viajante e para o financeiro/departamento de viagens, respectivamente.

Exemplo:

No caso em que o processo todo deve passar por aprovação ou conferência, temos:

Caso alguma etapa possa ser realizada automaticamente, temos:

Por fim, além das viagens, a rotina também permite efetuar prestações de contas avulsas.

A Conferência de Serviços nada mais é que o espelho da fatura de uma agência de viagens ou dos próprios fornecedores diretos (companhias aéreas, hotéis, locadoras de carros etc.).

Nesta rotina é possível selecionar os itens de viagens, seja por serviço ou considerando todos os tipos, para seleção e edição do pagamento enviado na fatura. Com os pedidos devidamente selecionados e os valores editados quando necessário, será gerado um pedido de compra, uma nota ou um título a pagar.

Quando existe um acordo entre fornecedor e cliente a respeito do pagamento de gastos das viagens, o Protheus permite faturar tanto a viagem completa como um prestação de contas avulsa.

O faturamento de uma viagem inclui os custos dos serviços contratados (voo, hotel, locação de carros, seguros e rodoviário) e os gastos dos colaboradores envolvidos. Quando todos os serviços estiverem pagos e a prestação de contas finalizada e aprovada, a viagem estará apta a ser faturada contra o cliente, seja parcial ou totalmente. Contudo, é possível parametrizar as regras de viagens e permitir o faturamento antecipado de uma viagem, desde que ao menos a prestação de contas esteja finalizada, uma vez que este é um custo variável, diferentemente dos serviços que possuem uma previsão na sua contratação.

Já as prestações de contas avulsas podem ser faturadas assim que finalizadas.

Para mais informações acesse os manuais de integração TOTVS X Reserve e PCO X Reserve.

O App Minha Prestação de Contas permite um controle fácil e rápido para que viajantes corporativos mantenham sua prestação de contas atualizada durante uma viagem.

Com este aplicativo é possível:

• Sincronizar as prestações de contas de viagens;
• Incluir uma prestação de contas avulsa;
• Gerir/Controlar despesas;
• Acompanhar o saldo da prestação de contas;
• Encaminhar uma prestação de contas para conferência e aprovação;
• Acompanhar as prestações de contas já encerradas;
• Corrigir as prestações de contas recusadas.

O mínimo deste processo que precisa estar configurado para o funcionamento do aplicativo é:

• Cadastros
  • Despesas (com ou sem amarração por localidade e grupo)
  • Grupo de acesso
  • Participantes
• Prestação de Contas (avulsa)

Já um processo completo de viagens para o App engloba:

• Cadastros
  • Wizard de Configuração
  • Participante
  • Grupo de Acesso
  • Despesa
  • Grupo de Despesa
• Solicitação de Viagem (Via integração Reserve ou Protheus)
• Viagem
• Adiantamento
• Prestação de Contas (foco do app)
  
  

Para mais informações acesse o TOTVS Minha Prestação de Contas na área do Aplicativos.

Para fazer o download do App acesse o Google Play.