Linha Microsiga Protheus

Árvore de páginas

Descrição

O ponto de entrada FI040MNCP é utilizado para a manipular as colunas do aBrowse da rotina de Consulta de Títulos a Receber (FINC040).

Veja Também

Para atender a Lei Geral de Proteção de Dados (Lei n° 13.70), alguns campos que apresentam informações consideradas como dados sensíveis, serão ofuscados deixando de ser legíveis.
Para tratar ofuscação de campos modificados por esse ponto de entrada, utilizar o Ponto de Entrada FI040CPCO .

Pré-condição

A execução do PE FI040MNCP está condicionada à presença dos PE's abaixo:

FI040TPCP - Define os tipos de colunas incluídas no aBrowse

FI040GRCP - Grava os campos incluídos no aBrowse

Exemplos


#INCLUDE "PROTHEUS.CH"
#INCLUDE "FINC040.CH"
#INCLUDE "PARMTYPE.CH"
 
//----------------------------------------------------------------------------------
/*/{Protheus.doc} FI040MNCP
Manipula as colunas do aBrowse na rotina de Consulta de Títulos a Receber (FINC040).

@return aBrowPE[1] = Nome da coluna a ser exibido em tela;
		aBrowPE[2] = Campo da tabela SE5 a ser adicionado;
/*/
//----------------------------------------------------------------------------------

User FUNCTION FI040MNCP()
    LOCAL aBrowPE := PARAMIXB[1] // Array para ser manipulado
 
    IF EMPTY(aBrowPE)
        aBrowPE:= {;
            {" ","OK"},; //Led de ativo, cancelado ou estornado
            {STR0010,"DATAX"},; //Data
            {STR0011,"JUROS"},; //Juros
            {STR0012,"MULTA"},; //Multa
            {STR0013,"CORRECAO"},; //Correção
            {STR0014,"DESCONTOS"},; //Descontos
            {STR0101,"VALACESS"},; //Valores Acessórios
            {STR0106,"VALORTRANS"},;//Valor Descontado
            {STR0015,"VALORRECEB"},;//Valor Recebido
            {STR0016,"MOTIVO"},; //Motivo
            {STR0017,"HISTORICO"},; //Hist¢rico
            {STR0018,"DATACONT"},; //Data Contabilização
            {STR0090,"DATADISP"},; //Data Contabilização
            {STR0019,"LOTE"},; //Lote
            {STR0020,"BANCO"},; //Banco
            {STR0021,"AGENCIA"},; //Agência
            {STR0022,"CONTA"},; //Conta
            {STR0023,"DOCUMENTO"},; //Documento
            {STR0081,"FILIAL"},; //Filial Movto.
            {STR0082,"RECONC"},; //Reconciliado
            {"ID","IDORIG"};
        }
    ENDIF

    IF ASCAN(aBrowPE,{|e| e[2] $ 'E5_BENEF' }) == 0
        AADD(aBrowPE,{"Campo1","E5_BENEF"}) // Campo 1 incluído pelo cliente
    ENDIF

    IF ASCAN(aBrowPE,{|e| e[2] $ 'E5_AUTBCO' }) == 0
        AADD(aBrowPE,{"Campo2","E5_AUTBCO"}) // Campo 2 incluído pelo cliente
    ENDIF
 
RETURN aBrowPE


Idioma

Português(Brasil)

Versões

Microsiga_Protheus11

Sistemas Operacionais Suportados

Todos

Compatível com as Bases de Dados

Todas

Retorno

aBrowPE - retorna array com as colunas manipuladas

Variáveis

aBrowPE - retorna array com as colunas manipuladas

Programa Fonte

FINC040.PRX