SetPrint - Configuração impressão de relatórios

#include "protheus.ch"

User Function TestImprime()

Local wnrel
Local cString  := "SA1"
Local titulo   := "Teste Impressão de Relatorios"
Local NomeProg := "XXX"                               
Local Tamanho := "M"
PRIVATE aReturn := { "Zebrado", 1,"Administracao", 1, 2, 1, "",1 }

wnrel:=SetPrint(cString,NomeProg,"",@titulo,"", "", "",.F.,.F.,.F.,Tamanho,,.F.)

If nLastKey <> 27
    SetDefault(aReturn,cString)
    If nLastKey <> 27
        RptStatus({|lEnd| U_TestRel(@lEnd,wnRel,cString,Tamanho,NomeProg)},titulo)
    EndIf
EndIf

Return 

User Function TestRel(lEnd,WnRel,cString,Tamanho,NomeProg)
LOCAL cabec1,cabec2
LOCAL cRodaTxt := oemtoansi("Rodapé")
Local nCntImpr 
Local nTipo                   

nCntImpr := 0
li := 80 
m_pag := 1

//³ Inicializa os codigos de caracter Comprimido da impressora ³
nTipo := 15

//³ Monta os Cabecalhos                                          ³
titulo:= oemtoansi("Lista de Clientes")
cabec1:= oemtoansi("COD LOJA NOME                                     NOME FANTASIA        ")
cabec2:=""        

dbSelectArea("SA1")

dbGoTop()

SetRegua(LastRec())

While !Eof()

    IncRegua()

    If Li > 60
        cabec(titulo,cabec1,cabec2,nomeprog,tamanho,15)
        @ Li,0 PSAY __PrtThinLine()                 
    Endif    

    nCntImpr++      
    Li++    

    @ Li,01 PSAY A1_COD    
    @ Li,05 PSAY A1_LOJA    
    @ Li,10 PSAY A1_NOME    
    @ Li,51 PSAY A1_NREDUZ    

    If Li > 60        
        Li:=66    
    Endif           

    dbSkip()

EndDO

If li != 80     
    Roda(nCntImpr,cRodaTxt,Tamanho)
EndIf

Set Device to Screen
If aReturn[5] = 1       
    Set Printer To      
    dbCommitAll()       
    OurSpool(wnrel)
Endif

MS_FLUSH()

Return