Page tree
Skip to end of metadata
Go to start of metadata

Rotina automática Bloco K (Conglomerados Econômicos) - Escrituração Contábil Digital

Características do Requisito

Linha de Produto:

Microsiga Protheus

Segmento:

Serviços

Módulo:

SIGACTB - Contabilidade Gerencial

Rotina:

Rotina

Nome Técnico

CTBS430

Cadastro do Bloco K - Plano de Contas Consolidado

CTBS440

Cadastro do Bloco K - Saldos das Contas Consolidadas

Tickets relacionados

2762031

País(es):

Todos homologados pelo Protheus.

Banco(s) de Dados:

Todos homologados pelo Protheus.

Tabelas Utilizadas:

CQU - SALDO CONTAS CONSOL BL K      

CQV - SALDO CONTAS CONSOL BL K      

CQX - SALDO CONTAS CONSOL BL K      

CQY - SALDO CONTAS CONSOL BL K      

CQZ - EMP CONTRAPARTES VL ELIM BL K 

Sistema(s) Operacional(is):

Todos homologados pelo Protheus.

Descrição

Abaixo exemplo de código a ser utilizado na execução automática das rotinas CTBS430 (Plano de Contas Consolidado) e CTBS440 (Cadastro do Bloco K - Saldos das Contas Consolidadas) utilizando o FWMVCRotAuto. 


Abaixo o código de execução automática da rotina CTBS430 (Plano de Contas Consolidado) :


#INCLUDE 'PROTHEUS.CH'
#INCLUDE 'FWMVCDEF.CH'
#INCLUDE 'CTBS430.CH'


User Function U_CTBS430()

Local aCabCQU := {}
Local aDetCQV := {}
Local aLinha := {}
Local nX := 0

Private oModel := Nil
Private lMsErroAuto := .F.

oModel := FwLoadModel ("CTBS430")

aRotina := MenuDef()

For nx := 1 To 10

aCabCQU := {}
aDetCQV := {}

AADD(aCabCQU, {"CQU_IDBLK" , "0000000001" ,NIL})
AADD(aCabCQU, {"CQU_CODNAT" , "01" ,NIL})
AADD(aCabCQU, {"CQU_INDCTA" , "A" ,NIL})
AADD(aCabCQU, {"CQU_CODCTA" , StrZero(nX,3) ,NIL})
AADD(aCabCQU, {"CQU_NOMCTA" , "CONTA " + StrZero(nX,3) ,NIL})
AADD(aCabCQU, {"CQU_NIVEL" , 1 ,NIL})
AADD(aCabCQU, {"CQU_CTASUP" , " " ,NIL})

aLinha := {}

AADD(aLinha, {"CQV_CODEMP" , "0001" })
AADD(aLinha, {"CQV_CTAEMP" , StrZero(nX,3) })

AADD(aDetCQV , aClone(aLinha))

aLinha := {}

AADD(aLinha, {"CQV_CODEMP" , "0002" })
AADD(aLinha, {"CQV_CTAEMP" , StrZero(nX,3) })

AADD(aDetCQV , aClone(aLinha))

FWMVCRotAuto(oModel, 'CQU', 3, { {'CQUMASTER',aCabCQU},{'CQVDETAIL',aDetCQV}})

If lMsErroAuto
MostraErro()
Exit
EndIf

Next nX

If !lMsErroAuto
MsgInfo("Cadastros Efetuados!", "Atenção")
EndIf

Return Nil

//-------------------------------------------------------------------
/*/{Protheus.doc} MenuDef
Menu da Rotina

@author TOTVS
/*/
//-------------------------------------------------------------------
Static Function MenuDef()

Return FWLoadMenuDef( "CTBS430")



Abaixo o código de execução automática da rotina CTBS440 (Cadastro do Bloco K - Saldos das Contas Consolidadas) :


#INCLUDE 'PROTHEUS.CH'
#INCLUDE 'FWMVCDEF.CH'
#INCLUDE 'CTBS440.CH'


User Function U_CTBS440()

Local aCabCQX := {}
Local aDetCQY := {}
Local aDetCQZ := {}
Local aLinha := {}
Local nX := 0

Private oModel := Nil
Private lMsErroAuto := .F.

oModel := FwLoadModel ("CTBS440")

aRotina := MenuDef()

For nx := 1 To 10
aCabCQX := {}
aDetCQY := {}
aDetCQZ := {}

AADD(aCabCQX, {"CQX_IDBLK" , "0000000001" ,NIL})
AADD(aCabCQX, {"CQX_CODCTA" , StrZero(nX + 3,3) ,NIL})
AADD(aCabCQX, {"CQX_VALAGL" , 1000 ,NIL})
AADD(aCabCQX, {"CQX_INDVAG" , "D" ,NIL})
AADD(aCabCQX, {"CQX_VALEL" , 100 ,NIL})
AADD(aCabCQX, {"CQX_INDVEL" , "C" ,NIL})
AADD(aCabCQX, {"CQX_VLCONS" , 1000 ,NIL})
AADD(aCabCQX, {"CQX_INDVCS" , "D" ,NIL})

aLinha := {}

AADD(aLinha, {"CQY_CODPAR" , "0001" })
AADD(aLinha, {"CQY_VLRELI" , 100 })
AADD(aLinha, {"CQY_INDELI" , "C" })

AADD(aDetCQY , aClone(aLinha))

aLinha := {}

AADD(aLinha, {"CQZ_EMPCPA" , "0002" })
AADD(aLinha, {"CQZ_CTACPA" , "002" })
AADD(aLinha, {"CQZ_VALELI" , 100 })
AADD(aLinha, {"CQZ_INDELI" , "D" })

AADD(aDetCQZ , aClone(aLinha))

FWMVCRotAuto(oModel, 'CQX', 3, { {'CQXMASTER',aCabCQX},{'CQYDETAIL',aDetCQY},{'CQZDETAIL',aDetCQZ}})

If lMsErroAuto
MostraErro()
Exit
EndIf

Next nX

If !lMsErroAuto
MsgInfo("Cadastros Efetuados!", "Atenção")
EndIf

Return Nil


//-------------------------------------------------------------------
/*/{Protheus.doc} MenuDef
Menu da Rotina

@author TOTVS
/*/
//-------------------------------------------------------------------
Static Function MenuDef()

Return FWLoadMenuDef("CTBS440")