VarEndT

Finaliza a transação em uma "chave", liberando novamente o acesso aos valores desta "chave" nas tabelas "Tabela X" e "Tabela A"

Sintaxe

VarEndT

lRet := VarEndT( <cUID>, <cChave> )

Parâmetros

Nome	Tipo	Descrição	Obrigatório	Referência	Observações
cUID	Caractere	Identificador da sessão de Variáveis Globais	X
cChave	Caractere	Identificador da chave	X

Retorno

Nome	Tipo	Descrição	Observações
lRet	Lógico	Indica se conseguiu finalizar a transação na chave <cChave> da sessão <cUID>	Retorna .T. se a função foi executada corretamente e se houver algum erro retorna .F.

Observações

Só deve ser finalizada uma transação em uma "chave" ("VarEndT"), que tenha previamente sido iniciada ("VarBeginT").

A transação em uma "chave" pode ser finalizada em um "Job/Thread" diferente do "Job/Thread" que iniciou a transação.

Disponível em Build igual ou superior a 7.00.131227A

Exemplos

Exemplo

User Function exemplo()
  Local cMyUID := "teste_UID_RL"
  Local cChave := "chave"
  Local aValor := {1, 2, 3}
  Local nValor := 0
  Local lRet := .F.
   
  lRet := VarSetUID(cMyUID)
  If(!lRet)
    ConOut("Erro na criação da sessão: " + cMyUID)
  EndIf
  
  lRet := VarBeginT(cMyUID, cChave)
  If(!lRet)
    ConOut("Erro na criação da transação na chave: " + cChave)
  Else
    // A transacao na chave foi iniciada
    ConOut("Iniciou a transação na chave: " + cChave)
 
    lRet := VarSetAD(cMyUID, cChave, aValor)
    If(!lRet)
      ConOut("Erro na atualização da chave (Tabela A): " + cChave)
    EndIf
 
    nValor := Len(aValor) - 1
    lRet := VarSetXD(cMyUID, cChave, nValor)
    If(!lRet)
      ConOut("Erro na atualização da chave (Tabela X): " + cChave)
    EndIf
 
    lRet := VarEndT(cMyUID, cChave)
    If(!lRet)
      ConOut("Erro ao finalizar a transação na chave: " + cChave)
    Else
      ConOut("Finalizou a transação na chave: " + cChave)
    EndIf
  EndIf
Return .T.

Veja também

VarSetUID, VarBeginT

Árvore de páginas